_____________________________________________________________________________

        Title: HOrSE  RaCiNG
      Version: 2.30
       Since : 04/18/1997
  Last update: 27/06/1997
       Author:  RATTANAM WONGKALASIN - B3703007@POPEYE.SUT.AC.TH
        Model:  Designed on a 9750,9850,9850PLUS,9950,9950 PLUS
  Description:  same "car racing" this idea of game I 'copy' from P'Peak
                more Fast if run in 9750
-----------------------------------------------------------------------------

COMMAND TRANSLATION:

                _        "display"              (SHIFT, VAR, F5)
                <>       "not equal to"         (SHIFT, VAR, F6, F3, F2)
                <=       "less than or equal to"(SHIFT, VAR, F6, F3, F6)
                >=       "more than or equal to"(SHIFT, VAR, F6, F3, F5)
                ->       "put in to"
                =>       "then"                 (SHIFT, VAR, F3, F3)
              Ran#       gives a random number. (OPTN, F6, F3, F4)
                /        divide

-----------------------------------------------------------------------------

PROGRAM CODE:

"HOrSE  RaCiNG"
V-window 1,127,0,1,63,0
Cls
Norm
Coordoff
0->A~Z
1000->B
Lbl 1
Cls
Do
ClrText
" "
" "
" "
" "
" "
Locate 4,1,"Now YOuR MonEY:"
Locate 9,3,"BahT"
B<=0=>Locate 10,2,0
B<=0=>Goto Z
Locate 4,4,"EntER 0 For EXIT"
10-Int ((log B)/2->A
Locate A,2,B
"U, WanT To BeT GaMe"?->C
C=0=>Goto Y
LpWhile Frac C<>0 Or C<=0 Or C>B
Text 10,3,"GoY"           'name of horse
Text 19,3,"DeN"           'name of horse
Text 28,3,"AoD"           'name of horse
Text 37,3,"TiT"           'name of horse 
Text 46,3,"NaM"           'name of horse
125->I
116->J
59->K
F-Line 1,10,1,K
F-Line 1,K,I,K
F-Line I,K,I,10
F-Line I,10,1,10
F-Line 1,57,I,57
F-Line 1,48,I,48
F-Line 1,39,I,39
F-Line 1,30,I,30
F-Line 1,21,I,21
F-Line 1,12,I,12
F-Line 17,10,17,K
F-Line J,10,J,K
F-Line J,1,J,7
F-Line J,7,118,6
F-Line 118,6,J,5
F-Line 114,1,118,1
Text 1,45,"HorSe RaciNG"
Text 57,5,"SeLeCt ThE HorSE NoW"
Lbl A
Plot 20,34_
0->D
For 1->A To 5
Y>=4+9A And Y<=11+9A=>A->D
Next
D=0=>Goto A
17->T~Z
Text 57,5,"RunNING..."
0->G~J
Lbl L
{1,2,3,4,5->List 1
For 1->A To 5
6-A->R
Int (RRan#+1->M
List 1[M->F
List 1[R->List 1[M
Int (3Ran#+1->E
If F=1
Then T+E->T
T>=116=>Goto B
F-Line T,13,T,20
IfEnd
If F=2
Then U+E->U
U>=116=>Goto B
F-Line U,22,U,29
IfEnd
If F=3
Then V+E->V
V>=116=>Goto B
F-Line V,31,V,38
IfEnd
If F=4
Then W+E->W
W>=116=>Goto B
F-Line W,40,W,47
IfEnd
If F=5
Then Z+E->Z
Z>=116=>Goto B
F-Line Z,49,Z,56
IfEnd
Next
Goto L
Lbl B
{T,U,V,W,Z->List 1
{1,2,3,4,5->List 2
SortD(List 1,List 2
List 1->List 3
Fill(0,List 3
For 1->I To 5
I->List 3[List 2[I
Next
For 1->I To 4
List 2[I->R
List 2[I+1->M
List 1[I]=List 1[I+1=>List 3[R->List 3[M
Next
120->M
For 1->I To 5
Text 9I+1,M,List 3[6-I
Next
57->Z
Text Z,1,"YOUR HORSE COME   ,ENtEr"
List 3[D->D
Text Z,70,D
PlotOn 0,0_
D=1=>2C+B->B
Text Z,70,"        "
D=1=>Text Z,1,"YOU DouBLE WiN, ENTer"
D=2=>C+B->B
D=2=>Text Z,1,"YOU WiN ,PreSs EntER"  
D=3=>Text Z,1,"YoU StaY ,ENteR NoW"
D=4=>B-C->B
D=4=>Text Z,1,"YOU LosT ,SeLEcT EnTeR"
D=5=>B-2C->B
D=5=>Text Z,1,"YoU DoUbLe LoST ,EnTeR"
PlotOn 0,0_
Goto 1
Lbl Z
"   YOU LoSt HA HA."_
Lbl Y
"End of game"
Stop

====================================
My Casio 9850 Game

1 IQMAX -My BEST CASIO CFX-9850 Game
2 XO-GOLD -Best of tic tac tae Game
3 PROCARD -3 in 1 game BLACKJACK, POGDENG, BLACKDENG
4 PUZZLE -Easy to write program but not easy to play
5 MINS SWEEPER -Same for win, Good game
6 CONFUSION -Same for win, Good game for test you memmory
7 HORSE RACING -Fun game
8 CALENDAR -9999 year Calendar viewer
9 NANNAN-T -2 in 1 game TOWERS OF HANOI and PAGED POWER
10 AND MORE...
=======================================
Thank for
Den Thana -idea for PROCARD
P'_Peak -original 9700 HORSE RACING and CROSS
THINK ,YO ,EAK ,UOD, BEE and more for test my games
AOD -for "make and test" Casio-to-Casio Cable and Casio-to-PC interface
NY R-COM -for idea and technical

(C) 1997 By Rattanam wongkalasin -NarM- Telecom Eng. SUT Thailand