DRUGWAR 2.0 (9700 version)

A Casio game from Happy Parrot Casio Games, ŠJoakim Knudsen 1997  joakimk@pihls.vgs.no
		visit Happy Parrot at http://come.to/happyparrot.casio.games

SIGN EXPLANATION:
@     means     theta
/     means     division
_     means     display
<=   means     lesser than or equal
>=   means     larger than or equal
<>   means      not equal
=>   means     then
->   means     assign


To avoid mixing of the digit zero and the letter O, I have entered all letters O as lowercase o's. This version of DrugWar is written especially for the 9700/9800 models. If you have a newer model, you have to get the 9x50 version.
Version 2.0 is a debugged version of the unusable version 1.0, upon which I received many complaints (naturally because it just didn't work at all!). Thanks for your notices, people! Enjoy.


Enter this in any program:

"DRUGWAR 2.0"
"J. KNUDSEN 1998"_
Lbl G
Mcl
2000->Z
5000->Y
100->K
1->B
2->@
100->T
Prog 2
"INSTRUCTIoNS"
"[1] YES  [0] No"
?->X
X=1=>Prog 1
Lbl @
Int 12000Ran#+16000->C
Int 7000Ran#+5000->H
(Int 34Ran#+10)x100->A
(Int 42Ran#+33)x10->W
(Int 15Ran#+7)x10->S
(Int 4Ran#+1)x10->L
Int 20Ran#+1->D
Prog 2
D=1=>"RIVAL DEALERS ARE SELLING CHEAP LUDES!!!"_
D=1=>2->L
D=2=>"WEED PRICES HAVE BoTToMED-oUT!!!"_
D=2=>122->W
D=3=>"PIGS ARE SELLING CHEAP HERoIN FRoM LAST WEEK'S RAID!!!"_
D=3=>Int 1150Ran#+850->H
D>3=>D<6=>"ADDICTS ARE BUYING HERoIN AT oUTRAGEoUS PRICES!!!"_
D>3=>D<6=>Int 25000Ran#+18000->H
D>5=>D<8=>"PIGS MADE A BIG CoKE-BUST!"
D>5=>D<8=>"PRICES ARE oUTRAGEoUS!"_
D>5=>D<8=>Int 60000Ran#+80000->C
D=8=>"YoU WERE MUGGED IN THE SUBWAY!"_
D=8=>Int (Z/3)->Z
0
D=15=>Z>299=>1
Ans=0=>Goto H
"WILL YoU BUY A NEW TRENCHCoAT WITH"
"MoRE PoCKETS FoR 200 BUCKS"?->X
X<>1=>Goto H
T+100->T
T-M-N-o-P-Q-R->K
Z-200->Z
Lbl H
D=14=>"THERE'S SoME WEED HERE THAT SMELLS LIKE GooD STUFF..."
D=14=>"WILL YoU SMoKE IT"?->X
D=14=>X=1=>"YoU HALLUCINATE oN THE WILDEST TRIP oF YoUR LIFE"
D=14=>X=1=>"YoU STUMBLE oNTo THE TRACKS, AND GET CREAMED BY A TRAIN!!"_
Goto C
0
Z>499=>K>4=>1
Ans=0=>Goto I
0
D>11=>D<14=>1
Ans=0=>Goto I
"WILL YoU BUY A"
Int 3Ran#->X
X=0=>"BARETTA"
X=1=>"SATURDAY NIGHT SPECIAL"
X=2=>".44 MAGNUM"
"FoR 400 DoLLARS"?->X
X<>1=>Goto I
Isz I
Z-400->Z
T-5->T
T-M-N-o-P-Q-R->K
Lbl I
0
D=16=>K>7=>1
Ans=0=>Goto R
Int 7Ran#+1->F
"YoU FoUND"
F=1=>"oNE UNIT"
F=2=>"TWo UNITS"
F=3=>"THREE UNITS"
F=4=>"FoUR UNITS"
F=5=>"FIVE UNITS"
F=6=>"SIX UNITS"
F=7=>"SEVEN UNITS"
Int 6Ran#->X
"oF"
X=0=>"LUDES"
X=1=>"SPEED"
X=2=>"WEED"
X=3=>"ACID"
X=4=>"HERoIN"
X=5=>"CoCAINE"
"oN A DEAD DUDE IN THE SUBWAY!"_
M[X]+F->M[X]
T-M-N-o-P-Q-R->K
Goto A
Lbl R
D=17=>"THE MARKET HAS BEEN FLooDED WITH CHEAP HoME-MADE ACID!!!"_
D=17=>Int 550Ran#+250->A
D=17=>Goto A
0
D>8=>D<12=>1
Ans=0=>Goto A
M+N+o+P+Q+R<50=>Goto A
D=9=>1->D
D=10=>3->D
D=11=>4->D
"oFFICER HARDASS AND"
D=1=>"oNE"
D=3=>"THREE"
D=4=>"FoUR"
"oF HIS DEPUTIES ARE AFTER YoU!"_
Lbl M
Prog 2
"BEING CHASED!!"
"[1]  VIEW GUNS"
"[2]  VIEW DAMAGE"
"[3]  NUMBER oF PIGS"
"[4]  RUN   [5]  FIGHT"?->X
X<1=>Goto M
X>5=>Goto M
Prog 2
X=1=>"YoU HAVE"
X=1=>I>0=>I_
X=1=>I=0=>"No"
X=1=>"GUNS"_
X=2=>"YoUR DAMAGE:"
X=2=>J_
" "
X=2=>"(50 DAMAGE, AND YoU DIE!)"_
X=3=>"THERE ARE"
X=3=>D+1_
X=3=>"PIGS STILL CHASING YoU!"_
X<4=>Goto M
X=5=>Goto J
"RUNNING..."
Prog 2
Int 2Ran#->X
X=0=>"YoU LoST THEM IN AN ALLEY!!"_
X=0=>B=31=>Goto A
X=0=>B<>31=>Goto @
X=1=>"YoU CAN'T SHAKE THEM!"_
X=1=>Goto o
Lbl J
I=0=>"YoU DoN'T HAVE ANY GUNS! YoU'LL HAVE To RUN!"_
I=0=>Goto M
Int 2Ran#->X
X=0=>"YoU MISSED!!!"_
X=1=>"YoU KILLED oNE!!"_
X=1=>Dsz D
X=1=>D<0=>Goto N
Lbl o
Prog 2
Int 2Ran#->X
"THEY'RE FIRING AT YoU!!"
X=0=>"THEY MISSED!!"_
X=0=>Goto M
"YoU'VE BEEN HIT!"_
J+3->J
J>49=>"YoU'VE BEEN KILLED!!"_
J>49=>Goto C
Goto M
Lbl N
Prog 2
"YoU KILLED ALL oF THEM!"_
Int 1250Ran#+750->X
Z+X->Z
Prog 2
"YoU FoUND"
X_
"DoLLARS oN oFFICER HARDASS' CARCASS!!"_
J=0=>Goto A
"YoU'RE HURT!"
Z<1200=>"BUT YoU CAN'T AFFoRD MEDICAL HELP..."_
Z<1200=>Goto A
"WILL YoU PAY 1000 DoLLARS FoR A DoCToR To SEW YoU UP"?->X
X<>1=>Goto A
Z-1000->Z
0->J
Lbl A
Prog 2
"[1]  SEE PRICES"
"[2]  TRENCHCoAT"
"[3]  BUY  [4]  SELL"
"[5]  JET  [6]  LoAN SHARK"
"[7]  VISIT BANK"?->X
X<1=>Goto A
X>7=>Goto A
Prog 2
"DAY NUMBER:"
B_
X=4=>Goto K
X=5=>Goto L
X=6=>Goto T
X=7=>Goto 4
"[C]  [H]  [A]  [W]  [S]  [L]"
X=2=>Goto V
X=3=>Goto W
Prog 2
"CoCAINE"
C_
"HERoIN"
H_
"ACID"
A_
"WEED"
W_
"SPEED"
S_
"LUDES"
L_
"WALLET"
Z_
"[DAY]"
B_
Goto A
Lbl V
Prog 2
"CoCAINE"
M_
"HERoIN"
H_
"ACID"
A_
"WEED"
W_
"SPEED"
S_
"LUDES"
L_
"FREE"
K_
Goto A
Lbl W
"WHAT To BUY"?->F
F<>C=>F<>H=>F<>A=>F<>W=>F<>S=>F<>L=>Goto W
Int (Z/F)->E
"YoU CAN AFFoRD"
E_
"UNITS."
"HoW MUCH"?->G
G>K=>Goto W
G<0=>Goto W
G>E=>Goto W
Z-FG->Z
F=C=>M+G->M
F=H=>N+G->N
F=A=>o+G->o
F=W=>P+G->P
F=S=>Q+G->Q
F=L=>R+G->R
T-M-N-o-P-Q-R->K
Goto A
Lbl K
"WHAT To SELL"?->F
F<>C=>F<>H=>F<>A=>F<>W=>F<>S=>F<>L=>Goto K
F=C=>M->E
F=H=>N->E
F=A=>o->E
F=W=>P->E
F=S=>Q->E
F=L=>R->E
"YoU HAVE"
E_
"HoW MUCH"?->G
G>E=>Goto K
G<0=>Goto K
F=C=>M-G->M
F=H=>N-G->N
F=A=>o-G->o
F=W=>P-G->P
F=S=>Q-G->Q
F=L=>R-G->R
Z+FG->Z
T-M-N-o-P-Q-R->K
Goto A
Lbl L
"WHERE To?"
"[1]  BRoNX  [2]  GHETTo"
"[3]  CENTRAL PARK"
"[4]  MANHATTAN"
"[5]  BRooKLYN"
"[6]  SUICIDE  [7]  STAY!"?->X
X<1=>Goto L
X>7=>Goto L
X=1=>@=2=>"YoU'RE ALREADY IN THE BRoNX!"_
X=1=>@=2=>Goto L
X=1=>2->@
X>1=>1->@
X=6=>Goto C
X=7=>Goto A
Prog 2
"SUBWAY"
Isz B
Int (1.1Y)->Y
Int (1.06V)->V
B=31=>Goto C
Goto @
Lbl T
@=1=>"THE LoAN SHARK oNLY DEALS IN THE BRoNX"_
@=1=>Goto A
Prog 2
Lbl Y
"LoAN SHARK"
"[1]  REPAY"
"[2]  BoRRoW"
"[3]  NEVER MIND"?->X
X<1=>Goto Y
X>3=>Goto Y
X=3=>Goto A
Lbl X
Prog 2
"DEBT:"
Y_
"WALLET:"
Z_
X=2=>Goto 5
"REPAY HoW MUCH"?->F
F>Z=>Goto X
F>Y=>Goto X
F<0=>Goto X
Y-F->Y
Z-F->Z
Goto A
Lbl 5
"BoRRoW HoW MUCH"?->F
F>50000=>"YoU THINK HE'S CRAZY, MAN?!"_
F>50000=>Goto 5
F<0=>Goto T
Y+F->Y
Z+F->Z
Goto A
Lbl 4
@=1=>"THE BANK IS IN THE BRoNX."_
@=1=>Goto A
Prog 2
"BANK"
"[1]  VIEW ACCoUNT"
"[2]  DEPoSIT"
"[3]  WITHDRAW"
"[4]  GooDBYE"?->X
X<1=>Goto 4
X>3=>Goto A
Lbl 2
Prog 2
"ACCoUNT:"
V_
"WALLET:"
Z_
X=1=>Goto 4
X=2=>"DEPoSIT HoW MUCH"?->G
X=2=>G>Z=>Goto 2
X=2=>V+G->V
X=2=>Z-G->Z
X=3=>"WITHDRAW HoW MUCH"?->F
X=3=>F>V=>F<>0=>Goto 2
X=3=>V-F->V
X=3=>Z+F->Z
Goto 4
Lbl C
Prog 2
"GAME oVER!"
"-----------"
V+Z-Y->V
V<0=>0->V
V>=0=>Int (sqrtV/31.5)->V      -- sqrt   is the square root symbol!
"SCoRE   (oUT oF 100):"
V_
"PLAY AGAIN"?->V
V=1=>Goto G
Prog 2
"THANKS FoR PLAYING!"
" "
"HAVE A NICE DAY!"



Enter this in program 1:

"DRUGWAR HELP"
"--------------"
"THIS IS A GAME"
"oF BUYING AND"
"SELLING. YoUR"
"GoAL IS To PAY"
"oFF YoUR DEBT To"
"THE LoAN SHARK"_
"AND THEN MAKE AS" 
"MUCH MoNEY AS"
"PoSSIBLE IN A 1"
"MoNTH PERIoD."_
"WATCH oUT FoR"
"THE PoLICE IF"
"YoU DEAL Too"
"HEAVILY!"_
"PRICES FoR DRUGS"
"ARE:"
"CoCAINE: 15000-28000"
"HERoIN: 5000-12000"
"ACID: 1000-4200"_
"WEED: 300-720"
"SPEED: 70-220"
"LUDES: 10-50"_
"GENERALLY, TYPE"
"THE FIRST LETTER"
"oF WHAT YoU WANT"
"To Do I.E.:"
"W=WEED L=LUDES"
"ETC..."_
"BUT 1=YES  0=No"_
"THE LAST NUMBER"
"IN THE PRICES"
"LIST IS YoUR"
"WALLET."_
THE LAST NUMBER"
"IN YoUR TRENCHCoAT
"IS FREE SPACE."_



Enter this in program 2

" ":" ":" ":" ":" "
"DRUGWAR!"